BelajarVBA 103 - ListBox

Coretan Mr. Kid

Belajar yuk.

Pada pembahasan tentang ComboBox, telah diulas tentang beberapa properti yang sering digunakan. Beberapa properti tersebut antara lain adalah Text, Value, ListIndex, BoundColumn, TextColumn, ColumnCount, dan sebagainya. Sebagian besar properti yang dimiliki oleh ComboBox juga dimiliki oleh ListBox.

Pembahasan kali ini adalah tentang ListBox. Sekilas akan diulang tentang properti yang juga dimiliki oleh ComboBox. Properti yang juga dimiliki oleh ComboBox yang akan turut dibahas kali ini adalah properti ListStyle. Pembahasan akan lebih mengkhususkan ke properti MultiSelect yang hanya dimiliki oleh ListBox. File tentang pembahasan ini dapat diunduh disini.

Sekilas properti yang dimiliki ListBox dan ComboBox

Pembahasan properti ComboBox pada coretan BelajarVBA 102 - ComboBox 02 dibagian bertajuk ComboBox list multi kolom hanya menampilkan satu kolom menggunakan sebuah userform bernama frmNomor3 yang berisi sebuah ComboBox bernama cboProd.

Sumber data ComboBox tersebut adalah range A2:C5 di dalam object sheet bernama Sheet2 seperti yang tampak pada gambar berikut ini.

Kali ini control ComboBox yang ada dalam userform frmNomor3 akan dibuang dan diganti dengan sebuah ListBox. ListBox tersebut akan diatur agar properti (Name), BoundColumn, ColumnCount, dan TextColumn memiliki nilai yang sama dengan yang diatur pada ComboBox, yaitu :

• (Name) diisi cboProd
• BoundColumn diisi 2
• ColumnCount diisi 1
• TextColumn diisi 1

Setelah seluruh ListBox pengganti telah diatur propertinya, maka userform frmNomor3 bisa dijalankan. Meskipun tidak ada script di dalam userform frmNomor3 yang diubah, userform bisa bekerja seperti semula dengan satu perbedaan yaitu penggunaan ListBox yang menggantikan ComboBox. Hal ini menunjukkan bahwa sebagian besar properti ComboBox juga dimiliki oleh ListBox. Cara penggunaannya, yaitu cara mengambil nilai atau mengisi nilai properti juga memiliki kesamaan. Userform frmNomor3 dalam file BelajarVBA102_02.xlsm dapat dibandingkan dengan yang ada dalam file BelajarVBA103.xlsm.

Membuat ListBox dapat dipilih lebih dari satu item

ListBox memiliki properti yang membuat user bisa memilih banyak item sekaligus. Properti ini bernama MultiSelect. Properti MultiSelect memiliki 3 (tiga) buah opsi, yaitu :

• Single : bernilai 0 [fmMultiSelectSingle], yaitu hanya dapat memilih satu item (seperti di ComboBox)
• Multi : bernilai 1 [fmMultiSelectMulti], yaitu bisa memilih banyak item, tetapi dipilih dengan mengklik setiap item
• Extended : bernilai 2 [fmMultiSelectExtended], yaitu bisa memilih banyak item dengan bantuan tombol SHIFT ataupun CTRL

Pengaturan properti MultiSelect bisa dilakukan saat proses design dengan langsung mengubah nilai properti melalui Properties Window milik VBE. Sedangkan pengaturan dengan menggunakan script adalah dengan syntax :

objectListBox.MultiSelect = nilai_opsi

• objectListBox : nama listbox atau isi dari properti (Name) maupun variabel yang menyimpan object control ListBox
• nilai_opsi : salah satu dari 3 (tiga) opsi yang telah dijelaskan di atas, yaitu fmMultiSelectSingle, fmMultiSelectMulti, atau fmMultiSelectExtended

Contoh :

Sebuah listbox bernama lstMulti akan di-set dengan script agar bisa membuat user memilih lebih dari satu item dengan cara mengklik item dan memanfaatkan tombol SHIFT maupun CTRL.

Bunyi baris perintahnya adalah :

lstMulti.MultiSelect = fmMultiSelectExtended

Status terpilih atau tidaknya sebuah item dalam ListBox

Sebuah item yang terpilih (Selected) akan memiliki latar dengan warna tertentu. Jika sebuah item yang sedang dalam keadaan terpilih kemudian diklik, maka statusnya akan berubah menjadi tidak terpilih. Properti yang menyimpan status terpilih atau tidaknya setiap item dalam ListBox adalah properti Selected. Jika nilai dalam properti Selected milik item dengan index tertentu adalah TRUE, maka item listbox pada index tersebut sedang dalam keadaan terpilih. Jika bernilai FALSE, maka item pada index tersebut sedang dalam keadaan tidak terpilih. Properti Selected dapat digunakan untuk memilih atau pun membatalkan pilihan pada suatu item dengan menggunakan script.

Baris perintah untuk mengetahui sebuah item dalam keadaan terpilih atau tidak adalah dengan syntax :

var_boolean_penyimpan = objectListBox.Selected(index)

• var_boolean_penyimpan : variabel bertipe Boolean yang akan menjadi penyimpan nilai status terpilih atau tidaknya item dengan index tertentu
• objectListBox : nama listbox atau isi dari properti (Name) maupun variabel yang menyimpan object control ListBox
• index : nomor index (base 0) item ListBox yang akan dicari ambil nilai status terpilih atau tidaknya

Contoh :

Ingin mengetahui status terpilih atau tidaknya item ke-5 (index ke-4 karena base 0) dalam sebuah listbox bernama lstMulti. Jika dalam keadaan terpilih, maka akan menampilkan pesan bertuliskan 'Terpilih'. Jika belum terpilih, maka akan menampilkan pesan 'Belum terpilih'.

Bunyi baris-baris perintahnya adalah :

Dim bStatus As Boolean
bStatus = lstMulti.Selected(4)
IF bStatus=TRUE Then
   Msgbox "Terpilih"
Else
   Msgbox "Belum terpilih"
End IF


Script di atas dapat disederhanakan menjadi :

IF lstMulti.Selected(4) Then
   Msgbox "Terpilih"
Else
   Msgbox "Belum terpilih"
End IF

Sedangkan baris perintah untuk mengubah status sebuah item menjadi terpilih atau tidak terpilih adalah dengan syntax :

objectListBox.Selected(index) = nilai_status_yang_baru

• objectListBox : nama listbox atau isi dari properti (Name) maupun variabel yang menyimpan object control ListBox
• index : nomor index (base 0) item ListBox yang akan dicari ambil nilai status terpilih atau tidaknya
• nilai_status_yang_baru : TRUE/FALSE, yaitu TRUE untuk membuat item dengan index tertentu menjadi dalam keadaan terpilih dan FALSE untuk membuat item dengan index tertentu tersebut tidak terpilih.

Contoh :

Sebuah listbox bernama lstMulti akan membuat item ke-3 (index bernilai 2 karena base 0) menjadi tidak terpilih.

Bunyi baris perintahnya adalah :

lstMulti.Selected(2) = FALSE

Mengetahui jumlah item yang terpilih

Jumlah item yang dipilih oleh user dalam sebuah multiselect listbox didapatkan melalui pembacaan status setiap itemnya. Berarti diperlukan proses loop dari item pertama sampai item terakhir. Dalam proses loop tersebut dilakukan pemeriksaan status terpilih atau tidaknya, yaitu melalui properti Selected. Jika statusnya adalah TRUE, maka variabel penampung jumlah item terpilih ditambah dengan satu.

Contoh :

Menampilkan kotak pesan berisi jumlah item yang terpilih pada listbox bernama lstMulti.

Bunyi baris-baris perintahnya adalah :

Dim lIdx As Long    'variabel loop per item dalam listbox lstMulti
Dim lTerpilih As Long    'variabel penyimpan jumlah item terpilih

For lIdx = 0 To lstMulti.ListCount - 1
   IF lstMulti.Selected(lIdx) Then
      lTerpilih = lTerpilih + 1
   End IF
Next lIdx
Msgbox "Jumlah item terpilih : " & lTerpilih

Bagi pembaca yang sudah familiar dengan fungsi-fungsi WInAPI, penggunaan fungsi WinAPI bernama SendMessage jauh lebih cepat dibanding menggunakan proses loop di atas.

Memilih seluruh item

Proses memilih atau membatalkan pilihan pada seluruh item dalam listbox juga dilakukan dengan melakukan loop terhadap seluruh item. Di dalam proses loop seluruh item hanya berisi baris perintah untuk mengubah nilai properti Selected pada index tersebut menjadi TRUE (untuk memilih) atau FALSE (untuk membatalkan pilihan).

Contoh :

Memilih seluruh itam yang ada pada listbox bernama lstMulti.

Bunyi baris-baris perintahnya adalah :

Dim lIdx As Long    'variabel loop per item dalam listbox lstMulti

For lIdx = 0 To lstMulti.ListCount - 1
   lstMulti.Selected(lIdx) = TRUE
Next lIdx
Msgbox "Proses selesai." & vbcrlf & "Seluruh item telah terpilih."

Contoh penggunaan listbox yang memanfaatkan properti MultiSelect dapat dilihat di file BelajarVBA103.xlsm pada sheet bernama MultiSelect. Penggunaan control Label juga telah disinggung pada file ini.

;)
Insya Allah pembahasan lebih detil tentang control Label dan TextBox bisa segera terwujud.

<previous | next>

Tweet